每一个使用频率都是极高的! excel中5个函数搭配+10个公式直接套用


    今天我们来盘点2021版本中以及365版本中,早已经更新的强大函数,如果你还不知道,一定要用起来,并且关于这些函数的突出的点在这一章我都写到了,大家可以参考一下。
    
    一、FILTER函数
    FILTER函数作为目前最强的函数之一,不但可以替代VLOOKUP函数,INDEX+MATCH函数等查找函数。
    还可以替代万金油公式,进行条件的批量查询。
    1、单条件批量查找
    =FILTER(A2:F18,C2:C18=H2)
    
    2、多条件批量查找
    =FILTER(A2:F18,(C2:C18=H2)*(B2:B18=I2))
    
    3、单类条件多种类查找
    =FILTER(A2:F18,ISNUMBER(MATCH(C2:C18,H2:H3,0)))
    
    二、XLOOKUP函数
    XLOOKUP函数最强的一点,并不是替代其他的若干个函数,毕竟类似于VLOOKUP,INDEX+MATCH都用习惯了。他最强的其实就是倒序查找而已。
    如下面这个表格,如果你想要查找。
    第一次玄慈的销售额,可以用VLOOKUP函数
    =VLOOKUP(H3,A1:F13,4,0)
    
    如果你想要查找最后一次玄慈的销售额:
    =XLOOKUP(H3,A2:A13,D2:D13,,,-1)
    
    三、UNIQUE函数
    UNIQUE的意思就是独特唯一的意思。如果如下表,你想要把A列内容做一个去除重复值的调取
    =UNIQUE(A2:A13)
    
    UNIQUE不但可以做单列去重,还可以做多列去重:
    =UNIQUE(A2:B13)
    
    UNIQUE搭配FILTER函数也是相得益彰,如下表,我想要把解决的内容进行调取去重。
    首先可以可以用FILTER函数进行单条件调取:
    FILTER(A2:C13,C2:C13="是")
    
    上述会存在很多重复值,如果你要做去重处理,可以在前方再搭配一个UNIQUE函数:
    =UNIQUE(FILTER(A2:C13,C2:C13="是"))
    
    四、TEXTJOIN函数
    TEXTJOIN函数在office2019以上才有,在2016版本中目前是隐藏函数,如下图,我想要把姓名做一个合并,并且中间用逗号隔开:
    =TEXTJOIN(",",TRUE,A2:A12)
    
    再看下面这个表格,我想要把岗位分别为不同等级的进行条件合并
    首先可以先输入FILTER函数:
    =FILTER($A$2:$A$12,$B$2:$B$12=E2,"")
    
    在写完FILTER之后,可以用TEXTJOIN函数进行合并:
    =TEXTJOIN(",",TRUE,FILTER($A$2:$A$12,$B$2:$B$12=E2,""))
    最后做一个双击下拉。
    
    五、SORT函数
    SORT整理的意思,可以根据情况进行排序。这个函数很简单,但是大家可以看看下面的这个案例,对你来说应该有不少的启发。
    下面这个表格我根据单条件,"安全检查",进行满足条件的内容调取
    FILTER(B2:D21,(A2:A21=F2))
    
    调取出来的内容,其实是根据数据表的顺序进行排列的,于是你可以输入:
    =SORT(FILTER(B2:D21,(A2:A21=F2)),1)
    对FILTER调取出来的内容进行排序
    SORT(FILTER结果,依据结果的哪一列排序)
    
  • 1代表FILTER输出的负责人列,
  • 2代表日期列,
  • 3代表检查此处列.

    你都可以试一试。
    
    如果你想做降序排列,可以如下输入
    =SORT(FILTER(B2:D21,(A2:A21=F2)),1,-1)
    接下来,我们可以做一些自动化的设置,首先选择开发工具,选择选择按钮。
    
    插入3个选择按钮分别放置在表头位置,选择其中一个按钮设置单元格链接,只需要选择一个按钮进行单元格链接就行,切记。
    
    这个时候,你会发现链接单元格会根据选择按钮选择变化而变化:
    
    接下来你可以把G4单元格和函数进行连接,如下图:
    
    最后的效果,选择哪一个按钮,就是对应把哪一列进行整理排序,更加方便观看。